100 REM MENU SELECTION WITH JOYSTICK
110 REM DISPLAY MENU WITH CURSOR
120 L=1510:V=0
130 POKE53281,0:PRINT"[147][144]SAMPLE MENU :":POKE53281,1:POKE L,81
140 PRINT"USE JOYSTICK TO CHOOSE LINE"
150 PRINT"THEN PRESS BUTTON TO SELECT"
160 PRINT"PAYROLLL PROGRAM"
170 PRINT"ACCOUNTS PAYABLE PROGRAM"
180 PRINT"ACCOUNTS RECEIVABLE"
190 PRINT"INVENTORY PROGRAM"
200 PRINT"STOCKHOLDER RECORDS"
210 PRINT"STOP RUN"
220 GOSUB 350:REM CHECK JOYSTICK AND BUTTON
230 REM SEE IF BUTTON WAS PRESSED
240 IF FB=0 THEN 460
250 REM IF JOYSTICK NOT UP OR DOWN
260 REM AND FIRE BUTTON WAS NOT PRESSED,
270 REM GO BACK TO SCAN KEYBOARD
280 REM CHECK FOR JOYSTICK UP
290 IF JD=1 THEN IF V>4 THEN 220
300 IF JD=1 THEN V=V+3:POKE L,96:L=L-120:POKE L,81:FOR I=1TO250:NEXTI:GOTO 220
310 REM CHECK FOR JOYSTICK DOWN
320 IF JD=2 THEN IF V<-7 THEN 220
330 IF JD=2 THEN V=V-3:POKE L,96:L=L+120:POKE L,81:FOR I=1TO250:NEXTI:GOTO 220
340 GOTO 220:REM GO BACK TO CHECK FOR JOYSTICK
350 REM CHECK FOR FIREBUTTON PRESSED
360 REM AND TO FIND JOYSTICK DIRECTION
370 REM FB IS FIREBUTTON VALUE
380 REM FB=0 IF PRESSED
390 REM FB=16 IF NOT PRESSED
400 JV=PEEK(56321)
410 FB=JV AND 16
420 JD=15-(JV AND 15)
430 REM JD=1 IF JOYSTICK UP
440 REM JD=2 IF JOYSTICK DOWN
450 RETURN
460 REM HERE IS WHERE YOU GO IF BUTTON IS PRESSED
470 FOR I=1 TO 250:NEXT I
480 IF V=6 THEN PRINT"[147]PAYROLL PROGRAM SELECTED":GOTO 540
490 IF V=3 THEN PRINT"[147]ACCOUNTS PAYABLE SELECTED":GOTO 540
500 IF V=0 THEN PRINT"[147]ACCOUNTS RECEIVABLE SELECTED":GOTO 540
510 IF V=-3 THEN PRINT"[147]INVENTORY PROGRAM SELECTED":GOTO 540
520 IF V=-6 THEN PRINT"[147]STOCKHOLDER RECORD PROGRAM":GOTO 540
530 IF V=-9 THEN PRINT"[147]END OF RUN":STOP
540 PRINT"PRESS BUTTON TO RETURN TO MAIN MENU"
550 REM WAIT HERE UNTIL BUTTON IS PRESSED
560 A=PEEK(56321) AND 16
570 IF A<>0 THEN 560
580 FOR I=1 TO 250:NEXT I:GOTO 130